109 lines
3.8 KiB
Text
109 lines
3.8 KiB
Text
/-
|
||
Copyright (c) 2024 Joseph Tooby-Smith. All rights reserved.
|
||
Released under Apache 2.0 license as described in the file LICENSE.
|
||
Authors: Joseph Tooby-Smith
|
||
-/
|
||
import HepLean.PerturbationTheory.Wick.Contraction
|
||
/-!
|
||
|
||
# Static Wick's theorem
|
||
|
||
-/
|
||
|
||
namespace Wick
|
||
|
||
noncomputable section
|
||
|
||
open HepLean.List
|
||
|
||
lemma static_wick_nil {I : Type} {f : I → Type} [∀ i, Fintype (f i)]
|
||
(q : I → Fin 2)
|
||
(le1 : (Σ i, f i) → (Σ i, f i) → Prop) [DecidableRel le1]
|
||
{A : Type} [Semiring A] [Algebra ℂ A]
|
||
(F : FreeAlgebra ℂ (Σ i, f i) →ₐ A)
|
||
(S : Contractions.Splitting f le1) :
|
||
F (ofListLift f [] 1) = ∑ c : Contractions [],
|
||
c.toCenterTerm f q le1 F S *
|
||
F (koszulOrder le1 (fun i => q i.fst) (ofListLift f c.normalize 1)) := by
|
||
rw [← Contractions.nilEquiv.symm.sum_comp]
|
||
simp only [Finset.univ_unique, PUnit.default_eq_unit, Contractions.nilEquiv, Equiv.coe_fn_symm_mk,
|
||
Finset.sum_const, Finset.card_singleton, one_smul]
|
||
dsimp [Contractions.normalize, Contractions.toCenterTerm]
|
||
simp [ofListLift_empty]
|
||
|
||
lemma static_wick_cons {I : Type} {f : I → Type} [∀ i, Fintype (f i)]
|
||
(q : I → Fin 2)
|
||
(le1 : (Σ i, f i) → (Σ i, f i) → Prop) [DecidableRel le1]
|
||
[IsTrans ((i : I) × f i) le1] [IsTotal ((i : I) × f i) le1]
|
||
{A : Type} [Semiring A] [Algebra ℂ A] (r : List I) (a : I)
|
||
(F : FreeAlgebra ℂ (Σ i, f i) →ₐ A) [OperatorMap (fun i => q i.1) le1 F]
|
||
(S : Contractions.Splitting f le1)
|
||
(ih : F (ofListLift f r 1) =
|
||
∑ c : Contractions r, c.toCenterTerm f q le1 F S * F (koszulOrder le1 (fun i => q i.fst)
|
||
(ofListLift f c.normalize 1))) :
|
||
F (ofListLift f (a :: r) 1) = ∑ c : Contractions (a :: r),
|
||
c.toCenterTerm f q le1 F S *
|
||
F (koszulOrder le1 (fun i => q i.fst) (ofListLift f c.normalize 1)) := by
|
||
rw [ofListLift_cons_eq_ofListLift, map_mul, ih, Finset.mul_sum,
|
||
← Contractions.consEquiv.symm.sum_comp]
|
||
erw [Finset.sum_sigma]
|
||
congr
|
||
funext c
|
||
have hb := S.h𝓑 a
|
||
rw [← mul_assoc]
|
||
have hi := c.toCenterTerm_center f q le1 F S
|
||
rw [Subalgebra.mem_center_iff] at hi
|
||
rw [hi, mul_assoc, ← map_mul, hb, add_mul, map_add]
|
||
conv_lhs =>
|
||
rhs
|
||
lhs
|
||
rw [ofList_eq_smul_one]
|
||
rw [Algebra.smul_mul_assoc]
|
||
rw [ofList_singleton]
|
||
rw [mul_koszulOrder_le]
|
||
conv_lhs =>
|
||
rhs
|
||
lhs
|
||
rw [← map_smul, ← Algebra.smul_mul_assoc]
|
||
rw [← ofList_singleton, ← ofList_eq_smul_one]
|
||
conv_lhs =>
|
||
rhs
|
||
rhs
|
||
rw [ofList_eq_smul_one, Algebra.smul_mul_assoc, map_smul]
|
||
rw [le_all_mul_koszulOrder_ofListLift_expand]
|
||
conv_lhs =>
|
||
rhs
|
||
rhs
|
||
rw [smul_add, Finset.smul_sum]
|
||
rw [← map_smul, ← map_smul, ← Algebra.smul_mul_assoc, ← ofList_eq_smul_one]
|
||
rhs
|
||
rhs
|
||
intro n
|
||
rw [← Algebra.smul_mul_assoc, smul_comm, ← map_smul, ← LinearMap.map_smul₂,
|
||
← ofList_eq_smul_one]
|
||
rw [← add_assoc, ← map_add, ← map_add, ← add_mul, ← hb, ← ofListLift_cons_eq_ofListLift, mul_add]
|
||
rw [Fintype.sum_option]
|
||
congr 1
|
||
rw [Finset.mul_sum]
|
||
congr
|
||
funext n
|
||
rw [← mul_assoc]
|
||
rfl
|
||
exact S.h𝓑p a
|
||
exact S.h𝓑n a
|
||
|
||
theorem static_wick_theorem {I : Type} {f : I → Type} [∀ i, Fintype (f i)]
|
||
(q : I → Fin 2)
|
||
(le1 : (Σ i, f i) → (Σ i, f i) → Prop) [DecidableRel le1] [IsTrans ((i : I) × f i) le1]
|
||
[IsTotal ((i : I) × f i) le1]
|
||
{A : Type} [Semiring A] [Algebra ℂ A] (r : List I)
|
||
(F : FreeAlgebra ℂ (Σ i, f i) →ₐ A) [OperatorMap (fun i => q i.1) le1 F]
|
||
(S : Contractions.Splitting f le1) :
|
||
F (ofListLift f r 1) = ∑ c : Contractions r, c.toCenterTerm f q le1 F S *
|
||
F (koszulOrder le1 (fun i => q i.fst) (ofListLift f c.normalize 1)) := by
|
||
induction r with
|
||
| nil => exact static_wick_nil q le1 F S
|
||
| cons a r ih => exact static_wick_cons q le1 r a F S ih
|
||
|
||
end
|
||
end Wick
|